8.х Как получить ОстаткиИОбороты регистра накопления без поледнего регистратора?

Написал такой код для проверки корректности вводимой ставки НДС по старым движениям:

Код:

   Если Источник.Движения.Найти("ПродажиНалоговыйУчет") <> Неопределено Тогда
        Если Источник.Движения.ПродажиНалоговыйУчет.Количество() > 0 Тогда
        
            ДоговораКонтрагентов = Источник.Движения.ПродажиНалоговыйУчет.ВыгрузитьКолонку("ДоговорКонтрагента");
        
            Запрос = Новый Запрос;
            Запрос.Текст = "ВЫБРАТЬ
                           |    ПродажиНалоговыйУчетОстатки.ДоговорКонтрагента,
                           |    ПродажиНалоговыйУчетОстатки.СтавкаНДС
                           |ИЗ
                           |    РегистрНакопления.ПродажиНалоговыйУчет.Остатки(&МоментВремени, ДоговорКонтрагента В (&ДоговораКонтрагентов)) КАК ПродажиНалоговыйУчетОстатки";
            Запрос.УстановитьПараметр("МоментВремени", Новый Граница(Источник.МоментВремени(), ВидГраницы.Исключая));
            Запрос.УстановитьПараметр("ДоговораКонтрагентов", ДоговораКонтрагентов);
            СтарыеДвижения = Запрос.Выполнить().Выгрузить();
        
            Для каждого Строка Из Источник.Движения.ПродажиНалоговыйУчет Цикл
                Стр = СтарыеДвижения.Найти(Строка.ДоговорКонтрагента, "ДоговорКонтрагента");
                Если ЗначениеЗаполнено(Стр) Тогда
                    Если Стр.СтавкаНДС <> Строка.СтавкаНДС Тогда
                        Сообщить("Ставка НДС по договору """ + Строка.ДоговорКонтрагента + """ не соотвествует ставке по которой были сделаны движения раньше (было """ + Стр.СтавкаНДС + """)");
                    КонецЕсли;
                КонецЕсли;
            КонецЦикла;
        
        КонецЕсли;
    КонецЕсли;

Но есть маленькое НО. если нет остаток в то контроль работать не будет. Хотел сделать ОстаткиИОбороты ВидГраницы.Исключая но там такого нет. Есть Движения и ДвиженияИГраницыПериода. Можно ли как-то подправить все-таки запрос чтобы получать всегда остатки?

Я это делаю в подписке на событие проведения документов. Не будет ли так что если я все-таки сделаю через ОстаткиИОброты с периодичностью Регистратор то это будет тормозить проведение в случае если регистраторов много?

А если ставка НДС в табличной части?

Решил вот таким способом:

Код:

Запрос = Новый Запрос;
Запрос.Текст = "ВЫБРАТЬ
  |   ПриобретенияНалоговыйУчет.ДоговорКонтрагента,
  |   ПриобретенияНалоговыйУчет.СтавкаНДС,
  |   ПриобретенияНалоговыйУчет.Амортизируется
  |ПОМЕСТИТЬ втДвиженияДокумента
  |ИЗ
  |   РегистрНакопления.ПриобретенияНалоговыйУчет КАК ПриобретенияНалоговыйУчет
  |ГДЕ
  |   ПриобретенияНалоговыйУчет.Регистратор = &Ссылка
  |;
  |
  |////////////////////////////////////////////////////////////////////////////////
  |ВЫБРАТЬ РАЗЛИЧНЫЕ
  |   ПриобретенияНалоговыйУчет.ДоговорКонтрагента КАК ДоговорКонтрагента,
  |   ПриобретенияНалоговыйУчет.Амортизируется КАК Амортизируется,
  |   ПриобретенияНалоговыйУчет.СтавкаНДС КАК СтавкаНДС,
  |   втДвиженияДокумента.СтавкаНДС КАК ТекДокСтавкаНДС,
  |   втДвиженияДокумента.Амортизируется КАК ТекДокАмортизируется
  |ИЗ
  |   втДвиженияДокумента КАК втДвиженияДокумента
  |     ЛЕВОЕ СОЕДИНЕНИЕ РегистрНакопления.ПриобретенияНалоговыйУчет КАК ПриобретенияНалоговыйУчет
  |     ПО втДвиженияДокумента.ДоговорКонтрагента = ПриобретенияНалоговыйУчет.ДоговорКонтрагента
  |       И (НЕ втДвиженияДокумента.СтавкаНДС = ПриобретенияНалоговыйУчет.СтавкаНДС
  |         ИЛИ НЕ втДвиженияДокумента.Амортизируется = ПриобретенияНалоговыйУчет.Амортизируется)
  |ГДЕ
  |   ПриобретенияНалоговыйУчет.МоментВремени <= &МоментВремени";

Запрос.УстановитьПараметр("Ссылка", Источник.Ссылка);
Запрос.УстановитьПараметр("МоментВремени", Новый МоментВремени(Источник.Дата, Источник.Ссылка));
РезультатЗапроса = Запрос.Выполнить();

Если НЕ РезультатЗапроса.Пустой() Тогда
   #Если ВнешнееСоединение Тогда
     Отказ = Истина;
   #Иначе
     Выборка = РезультатЗапроса.Выбрать();
     Пока Выборка.Следующий() Цикл
       Если НЕ Выборка.ТекДокСтавкаНДС = Выборка.СтавкаНДС Тогда
         Сообщить("Выбранная ставка НДС """ + Выборка.ТекДокСтавкаНДС + """ по договору """ + Выборка.ДоговорКонтрагента + """ не соответствует ставке по которая выбиралась раньше (было """ + Выборка.СтавкаНДС + """)");
       КонецЕсли;
       Если НЕ Выборка.ТекДокАмортизируется = Выборка.Амортизируется Тогда
         Сообщить("Выбранное значение """ + Выборка.ТекДокАмортизируется + """ для Поставка основных фондов по договору """ + Выборка.ДоговорКонтрагента + """ не соответствует той которая устанавливалась раньше(было """ + Выборка.Амортизируется + """)");
       КонецЕсли;     
     КонецЦикла;
   #КонецЕсли           
КонецЕсли;