8.х Как программно добавить в ТаблицуФормы колонки!?

Привет всем, есть 8.2 упр интерфейс, подскажите как добавить колонки в ТаблицуФормы?

Попробуй так

Код:

НоваяКолонка = Элементы.Добавить("ТвояКолонка", Тип("ПолеФормы"), ТвояТаблицаНаФорме);  
НоваяКолонка.ПутьКДанным = "Товары.Номенклатура";  //Таблица.ПолеТаблицы

а где же реквезитФормыВзначение и обратно ?

Код:

    //Опишем будущие колонки
    ТЗ = Новый ТаблицаЗначений;
    Для Каждого СтрМассива Из Массив Цикл
        ТЗ.Колонки.Добавить(СтрМассива);
    КонецЦикла;
  
    //Опишем массив реквизитов
    МассивРеквизитов = Новый Массив;
    МассивТипаВыбора = Новый Массив;
    МассивТипаВыбора.Добавить(Тип("ТаблицаЗначений"));
    ОписаниеТипаВыбора = Новый ОписаниеТипов(МассивТипаВыбора);
  
    //Добавим в массив реквизитов таблицу значений
    МассивРеквизитов.Добавить(Новый РеквизитФормы("ДанныеФайла", ОписаниеТипаВыбора));
  
    //Добавим в массив реквизитов колонки таблицы
    Для Каждого Колонка Из ТЗ.Колонки Цикл
        МассивРеквизитов.Добавить(Новый РеквизитФормы(Колонка.Имя, Колонка.ТипЗначения, "ДанныеФайла"));
    КонецЦикла;
  
    ИзменитьРеквизиты(МассивРеквизитов);
  
    //Добавим Таблицу на форму
    ТаблицаДанныхФайла             = Элементы.Добавить("ТаблицаДанныхФайла", Тип("ТаблицаФормы"));
    ТаблицаДанныхФайла.ПутьКДанным = "ДанныеФайла";
    ТаблицаДанныхФайла.Отображение = ОтображениеТаблицы.Список;
  
    //Добавим колонки
    Для Каждого Колонка Из ТЗ.Колонки Цикл
        НовыйЭлемент = Элементы.Добавить(Колонка.Имя, Тип("ПолеФормы"), ТаблицаДанныхФайла);
        НовыйЭлемент.Вид = ВидПоляФормы.ПолеВвода;
        НовыйЭлемент.ПутьКДанным = "ДанныеФайла." + Колонка.Имя;
    КонецЦикла;  
    ЗначениеВРеквизитФормы(ТЗ,"ДанныеФайла");

Спасибо всем )