8.х Небольшая проблемка в отчете

Люди, помогите.
Сам отчет работает, но теперь в запрос нужно добавить , что бы выдавал еще и номенклатуру.

Запрос.Текст = "ВЫБРАТЬ
|ВложенныйЗапрос.Контрагент,
|ВложенныйЗапрос.Номенклатура,
|СУММА(ВложенныйЗапрос.Стоимость) КАК Стоимость,
|СУММА(ВложенныйЗапрос.Сумма) КАК Сумма
|ИЗ
|(ВЫБРАТЬ Продажи.Контрагент КАК Контрагент,Продажи.Номенклатура как номенклатура,СУММА(Продажи.Стоимость) КАК Стоимость, 0 КАК Сумма
| ИЗ
|РегистрНакопления.Продажи КАК Продажи
|ГДЕ
|Продажи.Период МЕЖДУ &ДатаС И &ДатаПо
|СГРУППИРОВАТЬ ПО Продажи.Контрагент
|ОБЪЕДИНИТЬ ВСЕ
|ВЫБРАТЬ
|ВозвратТоваровОтПокупателя.Контрагент,ВозвратТоваровОтПокупателя.Товары.Номенклатура,0,ВозвратТоваровОтПокупателя.СуммаДокумента
|ИЗ
|Документ.ВозвратТоваровОтПокупателя КАК ВозвратТоваровОтПокупателя
|ГДЕ
|ВозвратТоваровОтПокупателя.Дата МЕЖДУ &ДатаС И &ДатаПо И
|ВозвратТоваровОтПокупателя.Комментарий ПОДОБНО ""%брак%"" И
|ВозвратТоваровОтПокупателя.Проведен = ИСТИНА) КАК ВложенныйЗапрос
|СГРУППИРОВАТЬ ПО ВложенныйЗапрос.Контрагент
|АВТОУПОРЯДОЧИВАНИЕ";

Если Номенклатуру не добовлять, то отчет работает, как только добовляешь, говорит, что табличные части нельзя обьеденить.

На вскидку вот так:

Код:

Запрос.Текст = "ВЫБРАТЬ
|ВложенныйЗапрос.Контрагент,
|ВложенныйЗапрос.Номенклатура,
|ВложенныйЗапрос.Стоимость КАК Стоимость,
|ВложенныйЗапрос.Сумма КАК Сумма
|ИЗ
|(ВЫБРАТЬ 
|Продажи.Контрагент КАК Контрагент,
|Продажи.Номенклатура КАК Номенклатура,
|Продажи.Стоимость КАК Стоимость, 
|0 КАК Сумма
| ИЗ
|РегистрНакопления.Продажи КАК Продажи
|ГДЕ
|Продажи.Период МЕЖДУ &ДатаС И &ДатаПо 
|ОБЪЕДИНИТЬ ВСЕ
|ВЫБРАТЬ
|ВозвратТоваровОтПокупателяТовары.Ссылка.Контрагент,
|ВозвратТоваровОтПокупателяТовары.Номенклатура,
|0,
|ВозвратТоваровОтПокупателяТовары.Ссылка.СуммаДокумента
|ИЗ
|Документ.ВозвратТоваровОтПокупателя.Товары КАК ВозвратТоваровОтПокупателяТовары
|ГДЕ
|ВозвратТоваровОтПокупателяТовары.Ссылка.Дата МЕЖДУ &ДатаС И &ДатаПо И
|ВозвратТоваровОтПокупателяТовары.Ссылка.Комментарий ПОДОБНО ""%брак%"" И
|ВозвратТоваровОтПокупателяТовары.Ссылка.Проведен = ИСТИНА) КАК ВложенныйЗапрос
|АВТОУПОРЯДОЧИВАНИЕ";

Только здесь без группировок, разберись с ними. Используй конструктор запроса.

Гм, в браках, например, по контрагенту "Магазин Вася", по каждой номенклатуре высыпает одну и ту же сумму брака- итоговую.

Код:

Запрос.Текст = 
"ВЫБРАТЬ
|	ВложенныйЗапрос.Контрагент,
|	ВложенныйЗапрос.Номенклатура,
|	ВложенныйЗапрос.Стоимость КАК Стоимость,
|	ВложенныйЗапрос.Сумма КАК Сумма
|ИЗ
|	(ВЫБРАТЬ
|		Продажи.Контрагент КАК Контрагент,
|		Продажи.Номенклатура КАК Номенклатура,
|		СУММА(Продажи.Стоимость) КАК Стоимость,
|		0 КАК Сумма
|	ИЗ
|		РегистрНакопления.Продажи КАК Продажи
|	ГДЕ
|		Продажи.Период МЕЖДУ &ДатаС И &ДатаПо
|	
|	СГРУППИРОВАТЬ ПО
|		Продажи.Контрагент,
|		Продажи.Номенклатура
|	
|	ОБЪЕДИНИТЬ ВСЕ
|	
|	ВЫБРАТЬ
|		ВозвратТоваровОтПокупателяТовары.Ссылка.Контрагент,
|		ВозвратТоваровОтПокупателяТовары.Номенклатура,
|		0,
|		СУММА(ВозвратТоваровОтПокупателяТовары.Ссылка.СуммаДокумента)
|	ИЗ
|		Документ.ВозвратТоваровОтПокупателя.Товары КАК ВозвратТоваровОтПокупателяТовары
|	ГДЕ
|		ВозвратТоваровОтПокупателяТовары.Ссылка.Дата МЕЖДУ &ДатаС И &ДатаПо
|		И ВозвратТоваровОтПокупателяТовары.Ссылка.Комментарий ПОДОБНО ""%брак%""
|		И ВозвратТоваровОтПокупателяТовары.Ссылка.Проведен = ИСТИНА
|	
|	СГРУППИРОВАТЬ ПО
|		ВозвратТоваровОтПокупателяТовары.Ссылка.Контрагент,
|		ВозвратТоваровОтПокупателяТовары.Номенклатура) КАК ВложенныйЗапрос
|АВТОУПОРЯДОЧИВАНИЕ";

То же самое получается.

Замени

Код:

"|        СУММА(ВозвратТоваровОтПокупателяТовары.Ссылка.СуммаДокумента)"

на

Код:

"|        СУММА(ВозвратТоваровОтПокупателяТовары.Сумма)"

Теперь то что доктор прописал. Можно кое что уточнить?
При формировании, если есть и браки и продажи, то формировала в одной строчке, а сейчас в разных. Т.е. сырок, есть и браки и возвраты - в разных строках, соответственно если есть продажа. брак -0, и наоборот, хотя товар один.

эээ..., а что за конфа? В УТ, вапример, возврат же тоже по продажам "двигает"

УТ для Казахстана кажись редакция 2,0

Вру - 2,2

Ну так возврат тож по продажам двигает, не правда ли?

да, но реально вытянуть через продажи возвраты с полями "комментарии"?

ну попробуй так:

Код:

Запрос.Текст = 
"ВЫБРАТЬ
|	ВложенныйЗапрос.Контрагент,
|	ВложенныйЗапрос.Номенклатура,
|	СУММА(ВложенныйЗапрос.Стоимость) КАК Стоимость,
|	СУММА(ВложенныйЗапрос.Сумма) КАК Сумма
|ИЗ
|	(ВЫБРАТЬ
|		Продажи.Контрагент КАК Контрагент,
|		Продажи.Номенклатура КАК Номенклатура,
|		СУММА(Продажи.Стоимость) КАК Стоимость,
|		0 КАК Сумма
|	ИЗ
|		РегистрНакопления.Продажи КАК Продажи
|	ГДЕ
|		Продажи.Период МЕЖДУ &ДатаС И &ДатаПо
|		И (НЕ Продажи.Регистратор.Комментарий ПОДОБНО ""%брак%"")
|	
|	СГРУППИРОВАТЬ ПО
|		Продажи.Контрагент,
|		Продажи.Номенклатура
|	
|	ОБЪЕДИНИТЬ ВСЕ
|	
|	ВЫБРАТЬ
|		ВозвратТоваровОтПокупателяТовары.Ссылка.Контрагент,
|		ВозвратТоваровОтПокупателяТовары.Номенклатура,
|		0,
|		СУММА(ВозвратТоваровОтПокупателяТовары.Ссылка.СуммаДокумента)
|	ИЗ
|		Документ.ВозвратТоваровОтПокупателя.Товары КАК ВозвратТоваровОтПокупателяТовары
|	ГДЕ
|		ВозвратТоваровОтПокупателяТовары.Ссылка.Дата МЕЖДУ &ДатаС И &ДатаПо
|		И ВозвратТоваровОтПокупателяТовары.Ссылка.Комментарий ПОДОБНО ""%брак%""
|		И ВозвратТоваровОтПокупателяТовары.Ссылка.Проведен = ИСТИНА
|	
|	СГРУППИРОВАТЬ ПО
|		ВозвратТоваровОтПокупателяТовары.Ссылка.Контрагент,
|		ВозвратТоваровОтПокупателяТовары.Номенклатура) КАК ВложенныйЗапрос
|
|СГРУППИРОВАТЬ ПО
|	ВложенныйЗапрос.Контрагент,
|	ВложенныйЗапрос.Номенклатура
|АВТОУПОРЯДОЧИВАНИЕ

Кажеться тут кое что нуно было подправить?
СУММА(ВозвратТоваровОтПокупателяТовары.Ссылка.СуммаДокумента)
на
СУММА(ВозвратТоваровОтПокупателяТовары.Сумма)

ага. ну как успехи?

Спасибо, большой! Сильно помогли, и на кое что глаза слегка открыли. Еще один момент.
(НЕ Продажи.Регистратор.Комментарий ПОДОБНО ""%брак%"") мне кажеться здесь не нужен.

Для "спасибо" есть отдельная кнопка

Если не будет, то суммы возвратов будут выводиться в два поля. Смоделируйте ситуацию по какой нить номенклатуре:
Продажа 100 р
Возврат 50 р с комментой "Брак".
Если без этого условия, то попадет:
Продажа: 50
Возврат: 50
С условием:
Продажа: 100
Возврат: 50