8.х БП Нету половины видов операций списания с рс

Добрый день
Подскажите из за чего могут быть не доступны некоторые виды операции , а точнее зарплата по ведомостям ?
Бух базовая 3.0.49.28
Зарплата ведется во внешней программе (Зарплата 3)

не настроено? часть появляется только после "включения" галочек и пунктов в настройках

точнее можно ?

Много случаев есть.
В базовой - если организация - ИП без наемных работников, то ЗП некому переводить когда-либо, даже в теории
А других организаций в базовой не может быть

организация

Не доступны именно потому, что зарплата ведется во внешней программе.

отключал делал "В этой программе" тоже самое даже если и стоит то как банк разносить ? там ведь не одной операции по зарплате
в других базах все доступны правда они проф

Я уже с этим встречался.
Но перепроверил

В базовой у ИП снимаю флажок "Используется труд наемных работников"
И всё - в списке выбора "Виды операций списания денежных средств" документа "Списание с расчетного счета" пропали присутствовавших ранее:

• Перечисление заработной платы по ведомостям
• Перечисление заработной платы работнику
• Перечисление сотруднику по договору подряда
• Перечисление депонированной заработной платы
  
• Выдача займа сотруднику
• др

А в Администрирование - Параметры учета - Настройки зарплаты - Учет расчетов по заработной платы и кадрового учета:

• В этой программе - выставлено

у меня ооо и такой галочки нету

Причина - какая-то банальная и определяется в пару минут при доступе к базе

На тот вопрос, что сформулирован "из за чего могут быть" - ответ был дан:

• так настроили базу, или
  
• что-то в ней настраивали (и уже попользовали) необратимо не так до этого или
  такую взяли для использования и толком не перенастроили по вашим условиям использования

ООООООО или АААААА - это только часть наименования, которое можно дать чему-угодно, в т.ч. и орг-ции вида "Индивидуальный предприниматель (ИП)" или номенклатуре
.
В БП 3.0 Организации имеют 2 предопределенных ида:

• Юридическое лицо (ООО, АО, ПАО)
  
• Индивидуальный предприниматель (ИП)

Нет такого наименования конфигурации, даже близко.

Конфигураций, содержащих в своём наименовании или отраслевых конфигураций, разработанных на основании "бух" и "ух" - десятки (если не сотни)

А у базовых, даже у одной только БП (Бухгалтерия предприятия), есть много преднастроенных разновидностей коробочных поставок, например у "1С:Бухгалтерия предприятия (базовая), редакция 3.0", которые в справке не показываются, но говорят о многом, что там заранее настроили (и вовремя не поменяли):

• 1С:Упрощенка, редакция 3.0;
  
• 1С:Предприниматель, редакция 3.0
• др

Юридическое лицо у меня
открыл старую базу до того как бухгалтер новый начал в ней работать там все операции есть
начал сравнивать обнаружил ,что учетная политика галочки одинаковые стоят , но отображается по другому
например в базе которую не кто не трогал ,где система налогообложения много пунктов в другой все три
Так же в учетной политике галочка "рассчитывать себестоимость услуг собственными подразделениями" ниже ,где выбирается автоматически есть еще поле "встречный выпуск продукции (услуг) в той нету такого поля
и не понятно вроде галки одинаково стоят

Столкнулся с такой же проблемой.
БП 3.0 (3.0.50.12). ООО.
Галка стоит: Учет расчетов по заработной платы и кадрового учета: В этой программе
Попробовал копирование старых док-тов с этим видом операции - не осуществляются движения.
Недавно было обновление, возможно связано с ним.

у меня 3.0.49.28

Если решите ,подскажите как ?)

Ребята, откройте вы уже конфигуратор:

Код:

Функция ПолучитьДоступныеЗначения(Отбор, СтрокаПоиска, ВызовИзПлатежногоПоручения)
   
    Исключения = Новый Массив;
   
    Исключения.Добавить(Перечисления.ВидыОперацийСписаниеДенежныхСредств.РасчетыПоКредитамИЗаймам);
   
    Организация = Неопределено;
    БанковскийСчет = Справочники.БанковскиеСчета.ПустаяСсылка();
    Если ТипЗнч(Отбор) = Тип("Структура") Тогда
        Если Отбор.Свойство("Организация") И ЗначениеЗаполнено(Отбор.Организация) Тогда
            Организация = Отбор.Организация;
        КонецЕсли;
       
        Если Отбор.Свойство("СчетОрганизации") И ЗначениеЗаполнено(Отбор.СчетОрганизации) Тогда
            БанковскийСчет = Отбор.СчетОрганизации;
        КонецЕсли;
    КонецЕсли;
   
    // Если отбор не передан, получим значение "по умолчанию", либо "единственную" организацию в ИБ.
    Если НЕ ЗначениеЗаполнено(Организация) Тогда
        Организация = Справочники.Организации.ОрганизацияПоУмолчанию();
    КонецЕсли;
   
    Если ЗначениеЗаполнено(Организация) Тогда
        ЭтоЮрЛицо = ОбщегоНазначенияБПВызовСервераПовтИсп.ЭтоЮрЛицо(Организация);
    Иначе
        ЭтоЮрЛицо = Истина; // ИП обычно ведет в базе только себя, а в этом случае организация будет получена.
    КонецЕсли;
   
    Если ВызовИзПлатежногоПоручения Тогда
        Исключения.Добавить(Перечисления.ВидыОперацийСписаниеДенежныхСредств.СнятиеНаличных);
        Исключения.Добавить(Перечисления.ВидыОперацийСписаниеДенежныхСредств.КомиссияБанка);
    КонецЕсли;
   
    Валютный = Ложь;
    Если ЗначениеЗаполнено(Организация) Тогда
        Если НЕ Справочники.БанковскиеСчета.ИспользуетсяНесколькоБанковскихСчетовОрганизации(Организация) Тогда
            Если НЕ ПолучитьФункциональнуюОпцию("ВестиУчетПоПодразделениям") Тогда
                Исключения.Добавить(Перечисления.ВидыОперацийСписаниеДенежныхСредств.ПереводНаДругойСчет);
            КонецЕсли;
        КонецЕсли;
       
        Если НЕ ЗначениеЗаполнено(БанковскийСчет) Тогда
            УчетДенежныхСредствБП.УстановитьБанковскийСчет(БанковскийСчет, Организация, Неопределено, Ложь);
        КонецЕсли;
       
        Если ЗначениеЗаполнено(БанковскийСчет) Тогда
            Валютный = ОбщегоНазначения.ЗначениеРеквизитаОбъекта(БанковскийСчет, "Валютный");
            Если Валютный Тогда
                Исключения.Добавить(Перечисления.ВидыОперацийСписаниеДенежныхСредств.ПеречислениеНалога);
            КонецЕсли;
        КонецЕсли;
    КонецЕсли;
   
    Если (НЕ УчетЗарплаты.ИспользуетсяПодсистемаУчетаЗарплатыИКадров()
        ИЛИ (НЕ ЭтоЮрЛицо И НЕ УчетЗарплаты.ИПИспользуетТрудНаемныхРаботников(Организация)))
        ИЛИ Валютный Тогда
        Исключения.Добавить(Перечисления.ВидыОперацийСписаниеДенежныхСредств.ПеречислениеЗП);
        Исключения.Добавить(Перечисления.ВидыОперацийСписаниеДенежныхСредств.ПеречислениеЗаработнойПлатыРаботнику);
        Исключения.Добавить(Перечисления.ВидыОперацийСписаниеДенежныхСредств.ПеречислениеДепонентов);
        Исключения.Добавить(Перечисления.ВидыОперацийСписаниеДенежныхСредств.ВыдачаЗаймаРаботнику);
        Исключения.Добавить(Перечисления.ВидыОперацийСписаниеДенежныхСредств.ПеречислениеСотрудникуПоДоговоруПодряда);
    КонецЕсли;
   
    Если ЭтоЮрЛицо ИЛИ НЕ ПолучитьФункциональнуюОпцию("ВестиУчетИндивидуальногоПредпринимателя") Тогда
        Исключения.Добавить(Перечисления.ВидыОперацийСписаниеДенежныхСредств.ЛичныеСредстваПредпринимателя);
    КонецЕсли;
   
    ДоступныеЗначения = Новый СписокЗначений;
    ЕстьНедоступные   = Ложь;
   
    Для каждого ЗначениеПеречисления Из Метаданные.Перечисления.ВидыОперацийСписаниеДенежныхСредств.ЗначенияПеречисления Цикл
       
        Если ТипЗнч(СтрокаПоиска) = Тип("Строка")
            И НЕ ПустаяСтрока(СтрокаПоиска)
            И СтрНайти(НРег(ЗначениеПеречисления.Синоним), НРег(СтрокаПоиска)) <> 1 Тогда
            Продолжить;
        КонецЕсли;
        Ссылка = Перечисления.ВидыОперацийСписаниеДенежныхСредств[ЗначениеПеречисления.Имя];
        Если ТипЗнч(Отбор) = Тип("ПеречислениеСсылка.ВидыОперацийСписаниеДенежныхСредств")
            И Отбор <> Ссылка Тогда
            Продолжить;
        ИначеЕсли ТипЗнч(Отбор) = Тип("ФиксированныйМассив")
            И Отбор.Найти(Ссылка) = Неопределено Тогда
            Продолжить;
        КонецЕсли;
        Если Исключения.Найти(Ссылка) <> Неопределено Тогда
            ЕстьНедоступные = Истина;
            Продолжить;
        КонецЕсли;
        ДоступныеЗначения.Добавить(Ссылка, ЗначениеПеречисления.Синоним);
       
    КонецЦикла;
   
    Возврат Новый Структура("ДоступныеЗначения,ЕстьНедоступные", ДоступныеЗначения, ЕстьНедоступные);
   
КонецФункции

--- Объединение сообщений, 17 июн 2017 ---

Если (НЕ УчетЗарплаты.ИспользуетсяПодсистемаУчетаЗарплатыИКадров()
ИЛИ (НЕ ЭтоЮрЛицо И НЕ УчетЗарплаты.ИПИспользуетТрудНаемныхРаботников(Организация)))
ИЛИ Валютный Тогда
Исключения.Добавить(Перечисления.ВидыОперацийСписаниеДенежныхСредств.ПеречислениеЗП);
Исключения.Добавить(Перечисления.ВидыОперацийСписаниеДенежныхСредств.ПеречислениеЗаработнойПлатыРаботнику);
Исключения.Добавить(Перечисления.ВидыОперацийСписаниеДенежныхСредств.ПеречислениеДепонентов);
Исключения.Добавить(Перечисления.ВидыОперацийСписаниеДенежныхСредств.ВыдачаЗаймаРаботнику);
Исключения.Добавить(Перечисления.ВидыОперацийСписаниеДенежныхСредств.ПеречислениеСотрудникуПоДоговоруПодряда);
КонецЕсли;

Не хватает определения ИспользуетсяПодсистемаУчетаЗарплатыИКадров() из общего модуля УчетЗарплаты

Код:

Функция ИспользуетсяПодсистемаУчетаЗарплатыИКадров() Экспорт

   УстановитьПривилегированныйРежим(Истина);
 
   Если Константы.УчетЗарплатыИКадровВоВнешнейПрограмме.Получить()
        ИЛИ Константы.УчетЗарплатыИКадровСредствамиБухгалтерии.Получить()  
  Тогда
     Возврат Истина;
   Иначе
     Возврат Ложь;
   КонецЕсли;
 
КонецФункции

Другими словами, будут не все опции "Виды операций списания денежных средств" в документе "Списание с расчетного счета" в случаях:

• или организация - ИП без наёмных работников
• или списание не в рублях
  
• или обе константы
  Учет Зарплаты И Кадров Во Внешней Программе
  Учет Зарплаты И Кадров Средствами Бухгалтерии
  одновременно равны Ложь (отсутствует крыжик в поле для них)

Добавлю, что мне не удалось отключить крыжики одновременно у обоих констант
В одной отключу, при отключении другой первая взводится и наоборот

А, вот, как это сделали и что делали спрашивающие для такого - у них надо в базе смотреть

т.к. переключение констант не помогло, я решил проверить Валюты и нашел дубль рубля полученный, судя по всему, обменом с УНФ.

Проверьте справочник Валюты, у вас случаем рубль не задублировался?
Если у вас тоже дубль, то будем рыть уже в этом направлении.

UPD: убрали второй рубль, теперь все ок.

Добрый день.
В моем случае в банковском счете организации не была указана валюта рубль. Как так произошло, не понятно. Ввели новый "правильный" банковский счет, обработкой группового изменения поменяли счет в банковских документах, счетах и проч.

После свертки базы, последующего переноса через универсальный обмен возникла ситуация, когда отсутствует часть видов операций в банковских выписках. Валюта, да, задвоилась. Но после её удаления проблема не решилась. Банковские счета новые не создавал. Просто перезаписал существующие. Проблема решилась.