8.х ОБМЕН Обмен между базами

Автоматом чтоли?

--- Объединение сообщений, 29 авг 2014 ---

Ставьте регламентное задание, которое будет по правилам выгружать нужные вам данные. И все. Делов то. Пример надо?

Я опишу как в моей базе это происходит. Дальше уже все на ваше усмотрение. Создал обычные правила обмена. У меня есть справочник Внешние обработки и т.д. Там я храню все свои правила. Затем создал регл задание и в общем модуле просто прописал этот код.

Код:

Процедура ВыгрузкаПоступленийВБухгалтериюОбщепита()

    НачатьТранзакцию();
    ЗапросПравил = Новый Запрос;
    ЗапросПравил.Текст =
    "ВЫБРАТЬ
    |    НастройкаРаботыСистемы.Аналитика1 КАК ИмяИнформационнойБазы,
    |    НастройкаРаботыСистемы.Аналитика2 КАК ПравилаОбмена,
    |    НастройкаРаботыСистемы.Аналитика3 КАК Организация,
    |    НастройкаРаботыСистемы.Аналитика4 КАК ДатаНачала,
    |    НастройкаРаботыСистемы.Аналитика5 КАК ДатаОкончания
    |ИЗ
    |    РегистрСведений.НастройкаРаботыСистемы КАК НастройкаРаботыСистемы
    |ГДЕ
    |    НастройкаРаботыСистемы.НомерНастройки = 18
    |
    |СГРУППИРОВАТЬ ПО
    |    НастройкаРаботыСистемы.Аналитика1,
    |    НастройкаРаботыСистемы.Аналитика2,
    |    НастройкаРаботыСистемы.Аналитика3,
    |    НастройкаРаботыСистемы.Аналитика4,
    |    НастройкаРаботыСистемы.Аналитика5";
    РезультатЗапросаПравил = ЗапросПравил.Выполнить();
    Если НЕ РезультатЗапросаПравил.Пустой() Тогда
        ВыборкаЗапросаПравил = РезультатЗапросаПравил.Выбрать();
        Пока ВыборкаЗапросаПравил.Следующий() Цикл
            ЗапросДоступа = Новый Запрос;
            ЗапросДоступа.Текст =
            "ВЫБРАТЬ
            |    НастройкаРаботыСистемы.Аналитика1 КАК ИмяИнформационнойБазы,
            |    НастройкаРаботыСистемы.Аналитика2 КАК ИмяСервера,
            |    НастройкаРаботыСистемы.Аналитика3 КАК ИмяПользователя,
            |    НастройкаРаботыСистемы.Аналитика4 КАК Пароль
            |ИЗ
            |    РегистрСведений.НастройкаРаботыСистемы КАК НастройкаРаботыСистемы
            |ГДЕ
            |    НастройкаРаботыСистемы.НомерНастройки = 19
            |    И НастройкаРаботыСистемы.Аналитика1 = &ИмяИнформационнойБазы
            |
            |СГРУППИРОВАТЬ ПО
            |    НастройкаРаботыСистемы.Аналитика1,
            |    НастройкаРаботыСистемы.Аналитика2,
            |    НастройкаРаботыСистемы.Аналитика3,
            |    НастройкаРаботыСистемы.Аналитика4";
            ЗапросДоступа.УстановитьПараметр("ИмяИнформационнойБазы", ВыборкаЗапросаПравил.ИмяИнформационнойБазы);
            РезультатЗапросаДоступа = ЗапросДоступа.Выполнить();
            Если НЕ РезультатЗапросаДоступа.Пустой() Тогда
                ВыборкаЗапросаДоступа = РезультатЗапросаДоступа.Выбрать();
                Пока ВыборкаЗапросаДоступа.Следующий() Цикл
                    ПравилаОбмена  = ВыборкаЗапросаПравил.ПравилаОбмена;
                    ДвоичныеДанные = ПравилаОбмена.ХранилищеВнешнейОбработки.Получить();
                    ИмяФайла       = ОбщиеФункции.УдалитьЗапрещенныеСимволыИмени(ПравилаОбмена.Наименование);
                    ПолноеИмяФайла = КаталогВременныхФайлов() + ИмяФайла + ".xml";
                    Попытка
                        ДвоичныеДанные.Записать(ПолноеИмяФайла);
                    Исключение
                        #Если Клиент Тогда
                            Сообщить(ОписаниеОшибки());
                        #КонецЕсли
                    КонецПопытки;
                    мУниверсальнаяВыгрузкаДанных = Обработки.УниверсальныйОбменДаннымиXML.Создать();
                    мУниверсальнаяВыгрузкаДанных.ИмяФайлаПравилОбмена = ПолноеИмяФайла;
                    мУниверсальнаяВыгрузкаДанных.ЗагрузитьПравилаОбмена();
                   
                    // Получим дату начала
                    ДатаНачала = '00010101';
                    ПолучитьПериод(ВыборкаЗапросаПравил.ДатаНачала, ДатаНачала);
                    мУниверсальнаяВыгрузкаДанных.ДатаНачала    = ДатаНачала;
                    // Получим дату окончания
                    ДатаОкончания = '00010101';
                    ПолучитьПериод(ВыборкаЗапросаПравил.ДатаОкончания, ДатаОкончания);
                    мУниверсальнаяВыгрузкаДанных.ДатаОкончания = ДатаОкончания;
                   
                    #Если Клиент Тогда
                        ОбработкаПрерыванияПользователя();
                    #КонецЕсли
                   
                    ВременнаяТаблицаПравил = мУниверсальнаяВыгрузкаДанных.ТаблицаПравилВыгрузки.Скопировать();
                    // Устанавливается отбор по организации...
                    Для каждого ТекСтрока Из мУниверсальнаяВыгрузкаДанных.ТаблицаНастройкиПараметров Цикл
                        Если ТекСтрока.Имя = "Организация" Тогда
                            ТекСтрока.Значение = ВыборкаЗапросаПравил.Организация;
                        КонецЕсли;
                    КонецЦикла;
                    мУниверсальнаяВыгрузкаДанных.НепосредственноеЧтениеВИБПриемнике              = Истина;
                    мУниверсальнаяВыгрузкаДанных.ТипИнформационнойБазыДляПодключения             = Ложь;
                    мУниверсальнаяВыгрузкаДанных.ВерсияПлатформыИнформационнойБазыДляПодключения = "V82";
                    мУниверсальнаяВыгрузкаДанных.ПользовательИнформационнойБазыДляПодключения    = ВыборкаЗапросаДоступа.ИмяПользователя;
                    мУниверсальнаяВыгрузкаДанных.ПарольИнформационнойБазыДляПодключения          = ВыборкаЗапросаДоступа.Пароль;
                    мУниверсальнаяВыгрузкаДанных.ИмяИнформационнойБазыНаСервереДляПодключения    = ВыборкаЗапросаДоступа.ИмяИнформационнойБазы;
                    мУниверсальнаяВыгрузкаДанных.ИмяСервераИнформационнойБазыДляПодключения      = ВыборкаЗапросаДоступа.ИмяСервера;
                    мУниверсальнаяВыгрузкаДанных.ТаблицаПравилВыгрузки                           = ВременнаяТаблицаПравил.Скопировать();
                    мУниверсальнаяВыгрузкаДанных.ВыполнитьВыгрузку();
                   
                    // Удаление временного файла, чтобы не занимать место на диске
                    Попытка
                        УдалитьФайлы(ПолноеИмяФайла);
                    Исключение
                        #Если Клиент Тогда
                            Сообщить(ОписаниеОшибки());
                        #КонецЕсли
                    КонецПопытки;
                КонецЦикла;
            Иначе
                #Если Клиент Тогда
                    Сообщить("Администратор: необходимо заполнить НРС. Настройка №19. Настройки доступа к базе БО для выгрузки поступлений.");
                #КонецЕсли
                Возврат;
            КонецЕсли;
        КонецЦикла;
    Иначе
        #Если Клиент Тогда
            Сообщить("Администратор: необходимо заполнить НРС. Настройка №18. Указать актуальные правила обмена для выгрузки поступлений.");
        #КонецЕсли
    КонецЕсли;
    ЗафиксироватьТранзакцию();

КонецПроцедуры

--- Объединение сообщений, 29 авг 2014 ---

Думаю, план обмена в Вашем, и в моем случае не нужен.

Ок. Вопрос. А если Вам вдруг потребуется, чтобы какой нибудь реквизит справочника менял свое значение в базе приемнике. Т.е. чтобы оно было отлично от базы источника. Что тогда делать будете?

Ну вот тогда и все. По моему методу, вам остается лишь написать свои правила обмена. И все. И чуток мой код подпилить под себя. Задача реально на пару часов. + отладка.