8.х Ошибка установки параметра сеанса

alexburn · 8 апр 2014

А они в каком порядке выполняются ???

nbIpKuH_BaH9I · 8 апр 2014

Матерь божья. Этож надо быть тупнем таким. Короче прав доступа не было.

X@ndr · 4 дек 2015

Dem0lisher сказал(а): ↑

Наверное не совсем верно поступил, но работает:
В модуле сеанса оставил только

Код:

Процедура УстановкаПараметровСеанса(ИменаПараметровСеанса)
 
    // СтандартныеПодсистемы
    СтандартныеПодсистемыСервер.УстановкаПараметровСеанса(ИменаПараметровСеанса);
    // Конец СтандартныеПодсистемы
КонецПроцедуры

А в модуле, где устанавливаются параметры "ТекущийПользователь" и "ТекущийВнешнийПользователь"
добавил еще одну строку "ПараметрыСеанса.Параметр = "1234567890";"

это общий модуль "ПользователиСлужебный" процедура "УстановкаПараметровСеанса"

Код:

// Заполняет параметр сеанса ТекущийПользователь или ТекущийВнешнийПользователь
// значением пользователя, найденному по пользователю информационной базы
// под которым запущен сеанс.
//  Если пользователь не найден, то при наличии административных прав
// создается новый пользователь в справочнике, иначе вызывается исключение.
//
Процедура УстановкаПараметровСеанса(Знач ИмяПараметра, УстановленныеПараметры) Экспорт
  
    Если ИмяПараметра <> "ТекущийПользователь"
       И ИмяПараметра <> "ТекущийВнешнийПользователь"
       И ИмяПараметра <> "Параметр" Тогда
        Возврат;
    КонецЕсли;
  
    УстановитьПривилегированныйРежим(Истина);
  
    Если НЕ ОбщегоНазначенияПовтИсп.ДоступноИспользованиеРазделенныхДанных() Тогда
        ВызватьИсключение
            НСтр("ru = 'Недопустимое получение параметра сеанса ТекущийПользователь
                       |в сеансе без указания всех разделителей.'");
    КонецЕсли;
  
    НачатьТранзакцию();
    Попытка
        ПользовательНеНайден = Ложь;
        СоздатьПользователя  = Ложь;
        СсылкаНового         = Неопределено;
        Служебный            = Ложь;
      
        ТекущийПользователь        = Неопределено;
        ТекущийВнешнийПользователь = Неопределено;
      
        ТекущийПользовательИБ = ПользователиИнформационнойБазы.ТекущийПользователь();
      
        ЭтоНеразделенныйПользователь = ОбщегоНазначенияПовтИсп.РазделениеВключено()
                                     И ТекущийПользовательИБ.РазделениеДанных.Количество() = 0;
      
        Если ПустаяСтрока(ТекущийПользовательИБ.Имя) Тогда
          
            ТекущийВнешнийПользователь = Справочники.ВнешниеПользователи.ПустаяСсылка();
          
            СвойстваНеуказанногоПользователя = СвойстваНеуказанногоПользователя();
          
            ИмяПользователя       = СвойстваНеуказанногоПользователя.ПолноеИмя;
            ПолноеИмяПользователя = СвойстваНеуказанногоПользователя.ПолноеИмя;
            СсылкаНового          = СвойстваНеуказанногоПользователя.СтандартнаяСсылка;
          
            Если СвойстваНеуказанногоПользователя.Ссылка = Неопределено Тогда
                ПользовательНеНайден = Истина;
                СоздатьПользователя  = Истина;
                Служебный = Истина;
                ИдентификаторПользователяИБ = "";
            Иначе
                ТекущийПользователь = СвойстваНеуказанногоПользователя.Ссылка;
            КонецЕсли;
        Иначе
            ИмяПользователя             = ТекущийПользовательИБ.Имя;
            ИдентификаторПользователяИБ = ТекущийПользовательИБ.УникальныйИдентификатор;
          
            Пользователи.НайтиНеоднозначныхПользователейИБ(, ИдентификаторПользователяИБ);
          
            Запрос = Новый Запрос;
            Запрос.Параметры.Вставить("ИдентификаторПользователяИБ", ИдентификаторПользователяИБ);
          
            Запрос.Текст =
            "ВЫБРАТЬ ПЕРВЫЕ 1
            |    Пользователи.Ссылка КАК Ссылка
            |ИЗ
            |    Справочник.Пользователи КАК Пользователи
            |ГДЕ
            |    Пользователи.ИдентификаторПользователяИБ = &ИдентификаторПользователяИБ";
            РезультатПользователи = Запрос.Выполнить();
          
            Запрос.Текст =
            "ВЫБРАТЬ ПЕРВЫЕ 1
            |    ВнешниеПользователи.Ссылка КАК Ссылка
            |ИЗ
            |    Справочник.ВнешниеПользователи КАК ВнешниеПользователи
            |ГДЕ
            |    ВнешниеПользователи.ИдентификаторПользователяИБ = &ИдентификаторПользователяИБ";
            РезультатВнешниеПользователи = Запрос.Выполнить();
          
            Если НЕ РезультатВнешниеПользователи.Пустой() Тогда
              
                Выборка = РезультатВнешниеПользователи.Выбрать();
                Выборка.Следующий();
                ТекущийПользователь        = Справочники.Пользователи.ПустаяСсылка();
                ТекущийВнешнийПользователь = Выборка.Ссылка;
              
                Если НЕ ВнешниеПользователи.ИспользоватьВнешнихПользователей() Тогда
              
                    ТекстСообщенияОбОшибке = НСтр("ru = 'Внешние пользователи отключены.'");
                    ВызватьИсключение ТекстСообщенияОбОшибке;
                КонецЕсли;
            Иначе
                ТекущийВнешнийПользователь = Справочники.ВнешниеПользователи.ПустаяСсылка();
              
                Если РезультатПользователи.Пустой() Тогда
                    Если ЭтоНеразделенныйПользователь
                     ИЛИ Пользователи.ЭтоПолноправныйПользователь( , , Ложь) Тогда
                      
                        ИдентификаторПользователяИБ = ТекущийПользовательИБ.УникальныйИдентификатор;
                      
                        Если ЭтоНеразделенныйПользователь Тогда
                            Служебный = Истина;
                            // ПолноеИмяПользователя заполняется ниже в транзакции.
                            ПользовательПоНаименованию  = Неопределено;
                        Иначе
                            ПолноеИмяПользователя       = ТекущийПользовательИБ.ПолноеИмя;
                            ПользовательПоНаименованию  = СсылкаПользователяПоПолномуНаименованию(ПолноеИмяПользователя);
                        КонецЕсли;
                      
                        Если ПользовательПоНаименованию = Неопределено Тогда
                            ПользовательНеНайден = Истина;
                            СоздатьПользователя  = Истина;
                        Иначе
                            ТекущийПользователь = ПользовательПоНаименованию;
                        КонецЕсли;
                    Иначе
                        ПользовательНеНайден = Истина;
                    КонецЕсли;
                Иначе
                    Выборка = РезультатПользователи.Выбрать();
                    Выборка.Следующий();
                    ТекущийПользователь = Выборка.Ссылка;
                КонецЕсли;
            КонецЕсли;
        КонецЕсли;
      
        Если СоздатьПользователя Тогда
          
            ЗарегистрироватьНеразделенногоПользователя();
          
            НачатьТранзакцию();
            Попытка
                Если ЭтоНеразделенныйПользователь И НЕ ПустаяСтрока(ТекущийПользовательИБ.Имя) Тогда
                    ПолноеИмяПользователя = Пользователи.ПолноеИмяСлужебногоПользователя(
                        ИдентификаторПользователяИБ);
                КонецЕсли;
              
                Если СсылкаНового = Неопределено Тогда
                    СсылкаНового = Справочники.Пользователи.ПолучитьСсылку();
                КонецЕсли;
              
                ТекущийПользователь = СсылкаНового;
              
                НовыйПользователь = Справочники.Пользователи.СоздатьЭлемент();
                НовыйПользователь.Служебный = Служебный;
                НовыйПользователь.Наименование = ПолноеИмяПользователя;
                НовыйПользователь.УстановитьСсылкуНового(СсылкаНового);
              
                Если ЗначениеЗаполнено(ИдентификаторПользователяИБ) Тогда
                  
                    ОписаниеПользователяИБ = Новый Структура;
                    ОписаниеПользователяИБ.Вставить("Действие", "Записать");
                    ОписаниеПользователяИБ.Вставить(
                        "УникальныйИдентификатор", ИдентификаторПользователяИБ);
                  
                    НовыйПользователь.ДополнительныеСвойства.Вставить(
                        "ОписаниеПользователяИБ", ОписаниеПользователяИБ);
                КонецЕсли;
              
                НовыйПользователь.Записать();
              
                ЗафиксироватьТранзакцию();
            Исключение
                ОтменитьТранзакцию();
              
                ТекстСообщенияОбОшибке = СтроковыеФункцииКлиентСервер.ПодставитьПараметрыВСтроку(
                    НСтр("ru = 'Авторизация не выполнена. Работа системы будет завершена.
                               |Пользователь: %1 не найден в справочнике ""Пользователи"".
                               |
                               |При попытке добавления пользователя в справочник возникла ошибка:
                               |""%2"".
                               |
                               |Обратитесь к администратору.'"),
                    ИмяПользователя,
                    КраткоеПредставлениеОшибки(ИнформацияОбОшибке()) );
              
                ВызватьИсключение ТекстСообщенияОбОшибке;
            КонецПопытки;
          
        ИначеЕсли ПользовательНеНайден Тогда
            ВызватьИсключение ТекстСообщенияПользовательНеНайденВСправочнике(ИмяПользователя);
        КонецЕсли;
      
        ЗафиксироватьТранзакцию();
    Исключение
        ОтменитьТранзакцию();
        ВызватьИсключение;
    КонецПопытки;
  
    Если ТекущийПользователь = Неопределено
     ИЛИ ТекущийВнешнийПользователь = Неопределено Тогда
      
        ТекстСообщенияОбОшибке = ТекстСообщенияПользовательНеНайденВСправочнике(ИмяПользователя) +
            НСтр("ru = '
                       |Возникла внутренняя ошибка при поиске пользователя.'");
        ВызватьИсключение ТекстСообщенияОбОшибке;
    КонецЕсли;
  
    ПараметрыСеанса.ТекущийПользователь        = ТекущийПользователь;
    ПараметрыСеанса.ТекущийВнешнийПользователь = ТекущийВнешнийПользователь;
    ПараметрыСеанса.Параметр = "1234567890";
  
    УстановленныеПараметры.Добавить("ТекущийПользователь");
    УстановленныеПараметры.Добавить("ТекущийВнешнийПользователь");
    УстановленныеПараметры.Добавить("Параметр");
  
КонецПроцедуры

Нажмите, чтобы раскрыть...

Спасибо за опубликованное решение!

Good_Smile · 28 май 2019

nbIpKuH_BaH9I сказал(а): ↑

Матерь божья. Этож надо быть тупнем таким. Короче прав доступа не было.
Нажмите, чтобы раскрыть...

Здравствуйте! Подскажите пожалуйста, правильно ли я поняла, что необходимо было дать права на установку всем пользователям?
Также столкнулась с этой проблемой. Параметр сеанса типовой - ВерсияРасширений, права соответственно тоже типовые, на установку только у Полных прав, для пользователей только Получение.
Или же необходимо было дать права на чтение того типа значения, которое указано в параметре сеанса?

nbIpKuH_BaH9I · 29 май 2019

Добрый день. Я конечно же не помню уже что там было((

Raider · 29 май 2019

Good_Smile сказал(а): ↑

Здравствуйте! Подскажите пожалуйста, правильно ли я поняла, что необходимо было дать права на установку всем пользователям?
Также столкнулась с этой проблемой. Параметр сеанса типовой - ВерсияРасширений, права соответственно тоже типовые, на установку только у Полных прав, для пользователей только Получение.
Или же необходимо было дать права на чтение того типа значения, которое указано в параметре сеанса?
Нажмите, чтобы раскрыть...

Тут либо давать права на установку, либо перед установкой делать УстановитьПривилегированныйРежим(Истина)

ТехБухПривет · 29 май 2019

Если правильно понял, что там было - то просто у пользователя не было прав даже на просмотр параметра сеанса... Доступ к параметрам сеанса должен быть почти у всех за исключением редких случаев!

Войти или зарегистрироваться

8.х Ошибка установки параметра сеанса

alexburn Модераторы Команда форума Модератор

nbIpKuH_BaH9I Модераторы Команда форума Модератор

[email protected] Новичок в 1С

Good_Smile

nbIpKuH_BaH9I Модераторы Команда форума Модератор

Raider Опытный в 1С

ТехБухПривет Профессионал в 1С Команда форума

8.х ошибка при установки

[РЕШЕНО] ВДРУГ ВОЗНИКЛА ОШИБКА --пытка получения неинициализированного значения параметра сеанса

8.х ошибка при установки платформы 8,3

Войти или зарегистрироваться

8.х Ошибка установки параметра сеанса

alexburn Модераторы Команда форума Модератор

nbIpKuH_BaH9I Модераторы Команда форума Модератор

[email protected] Новичок в 1С

Good_Smile

nbIpKuH_BaH9I Модераторы Команда форума Модератор

Raider Опытный в 1С

ТехБухПривет Профессионал в 1С Команда форума

8.х ошибка при установки

[РЕШЕНО] ВДРУГ ВОЗНИКЛА ОШИБКА --пытка получения неинициализированного значения параметра сеанса

8.х ошибка при установки платформы 8,3

Быстрый поиск