8.х Отбор в СКД по итоговым значениям группировки

Добрый день.
Конфигурация УТ, НЕ типовая.
Есть отчет на СКД (схему прикладываю), данные берет из 4-х регистров накопления: РасчетыСКлиентами, РасчетыСПоставщиками, ДополнительныеРасчетыСКлиентами, ДополнительныеРасчетыСПоставщиками.
Допустим,
РасчетыСКлиентами возвращает данные "Контрагент1.... +1500р." (контрагент1 должен нам 1500р. как клиент);
РасчетыСПоставщиками возвращает данные "Контрагент1.... -1000р." (контрагент1 должны мы 1000р. как поставщику)
Если никаких отборов нет, отчет выводит правильный результат: "Контрагент1....+500р."
Теперь я хочу видеть в отчете только долги (итоговые, по обоим регистрам). Накладываю отбор: "Сумма>0". Должен получить в отчете тот же результат: "Контрагент1....+500р.". Но получаю "Контрагент1....+1500р.", т.е. отбор накладывается до того как записи из разных регистров суммировались. Что, в моем случае, не правильно.
Как быть?

Немного разобрался. Надо отбор "Сумма>0" наложить не на весь отчет в целом, а на группировку "Контрагент".
Но в моем случае отбор накладывать программно, а программно я умею накладывать отбор только на весь отчет:

Код:

            ЭлОтбора = Отбор.Элементы.Добавить(Тип("ЭлементОтбораКомпоновкиДанных"));
            ПолеКД                        = Новый ПолеКомпоновкиДанных(УстанавливаемыйОтбор.ЛевоеЗначение);
            ЭлОтбора.ВидСравнения         = УстанавливаемыйОтбор.ВидСравнения;
            ЭлОтбора.ЛевоеЗначение        = ПолеКД;
            ЭлОтбора.Использование        = Истина;
            ЭлОтбора.ПравоеЗначение        = УстанавливаемыйОтбор.ПравоеЗначение;

Вобщем теперь задача такая: либо программно научиться накладывать отбор на группировку отчета, либо поправить отчет так, чтобы он правильно выводил данные и с отбором налоденным на весь отчет.
Подскажите чего-нибудь?

А как указать на что отбор накладывать? Это вообще возможно?

Несомненно Но пока не получается.

Вот тут предлагают сделать следующим образом, но у меня реквизит "отбор" отсутствует "НовыйЭлементОтбора = КомпоновщикНастроек.Настройки.Структура[0].Отбор"

/threads/programmno-ustanovit-otbor-v-skd.13221/

Код:

НовыйЭлементОтбора = КомпоновщикНастроек.Настройки.Структура[0].Отбор.Элементы.Добавить(Тип("ЭлементОтбораКомпоновкиДанных"));
НовыйЭлементОтбора.ЛевоеЗначение = КомпоновщикНастроек.Настройки.ДоступныеПоляОтбора.НайтиПоле(Новый ПолеКомпоновкиДанных("Организация")).Поле;
НовыйЭлементОтбора.ПравоеЗначение = Организация;

nomad_irk, спасибо. Получилось вот так:

Код:

Для Каждого ЭлементСтруктурыНастроек Из Настройки.Структура Цикл
                 Если ТипЗнч(ЭлементСтруктурыНастроек)= Тип("ТаблицаКомпоновкиДанных") Тогда
                    СтрокиТаблицыКомпановкиДанных = ЭлементСтруктурыНастроек.Строки;
                    Для Каждого СтрокаТаблицыКомпановкиДанных из СтрокиТаблицыКомпановкиДанных Цикл
                        Если ТипЗнч(СтрокаТаблицыКомпановкиДанных) = Тип("ГруппировкаТаблицыКомпоновкиДанных")
                            И НаименованиеГруппировки = Строка(СтрокаТаблицыКомпановкиДанных.ПоляГруппировки) Тогда
                          
                            УстановитьОтбор(СтрокаТаблицыКомпановкиДанных.Отбор, УстанавливаемыйОтбор);
                            ОтборУстановлен = Истина;
          
                        КонецЕсли;
                      
                    КонецЦикла;
                   
                 КонецЕсли;
            КонецЦикла;[/LEFT]

Код:

Процедура УстановитьОтбор(Отбор, УстанавливаемыйОтбор)
   
    ЭлОтбора = Отбор.Элементы.Добавить(Тип("ЭлементОтбораКомпоновкиДанных"));
    ПолеКД                        = Новый ПолеКомпоновкиДанных(УстанавливаемыйОтбор.ЛевоеЗначение);
    ЭлОтбора.ВидСравнения         = УстанавливаемыйОтбор.ВидСравнения;
    ЭлОтбора.ЛевоеЗначение        = ПолеКД;
    ЭлОтбора.Использование        = Истина;
    ЭлОтбора.ПравоеЗначение        = УстанавливаемыйОтбор.ПравоеЗначение;
       
КонецПроцедуры

где Настройки = СхемаКомпоновкиДанных.НастройкиПоУмолчанию;

Наверняка, не для всех отчетов на СКД работать будет. Но мне пока достаточно.​