[РЕШЕНО] Почему из отчета не открывается ссылка на документ?

В отчете в СКД делаю такие настройки.



Когда формирую отчет и навожу на номенклатуру вижу жирный белый крестик. Без лупы. Ссылка по щелчку не открывается. Что я упустил? В вгружаемой в НаборДанныхОбъект таблице номенклатура поле номенклатура имеет тип СправочникСсылка.Номенклатура.

Уже и расшифровку написал:

Код:

Процедура РезультатОбработкаРасшифровки(Элемент, Расшифровка, СтандартнаяОбработка)
  
    Перем ВыполненноеДействие;
    Перем ПараметрыВыбранногоДействия;
    // Запретим стандартную обработку расшифровки
    СтандартнаяОбработка = Ложь;
    // Создадим и инициализируем обработчик расшифровки  
    СхемаКомпоновкиДанных = ПолучитьМакет("ОсновнаяСхемаКомпоновкиДанных");
    ИсточникДоступныхНастроек = Новый ИсточникДоступныхНастроекКомпоновкиДанных(СхемаКомпоновкиДанных);
    ОбработкаРасшифровки = Новый ОбработкаРасшифровкиКомпоновкиДанных(ДанныеРасшифровки, ИсточникДоступныхНастроек);  
    //Перечень возможных действий
    ДоступныеДействия = Новый Массив();    ДоступныеДействия.Добавить(ДействиеОбработкиРасшифровкиКомпоновкиДанных.ОткрытьЗначение);  
    // Осуществим выбор действия расшифровки пользователем
    НастройкиСКД = ОбработкаРасшифровки.Выполнить(Расшифровка, ВыполненноеДействие, ДоступныеДействия);  
    Если ВыполненноеДействие = ДействиеОбработкиРасшифровкиКомпоновкиДанных.ОткрытьЗначение Тогда
        ОткрытьЗначение(ПараметрыВыбранногоДействия);
    КонецЕсли;             
  
КонецПроцедуры

Все равно не работает

Вероятно, что при программной компоновке отчета не указывается расшифровка

Вот как я компоную отчет:

Код:

//КомпоновщикНастроек
КомпНастроек = Новый КомпоновщикНастроекКомпоновкиДанных;
ИсточникДоступныхНастроек = Новый ИсточникДоступныхНастроекКомпоновкиДанных(СхемаКомпоновкиДанных);
КомпНастроек.Инициализировать(ИсточникДоступныхНастроек);
КомпНастроек.ЗагрузитьНастройки(КомпоновщикНастроек.ПолучитьНастройки());
Настройки = КомпНастроек.ПолучитьНастройки();  
      
//КомпоновщикМакета
КомпоновщикМакета = Новый КомпоновщикМакетаКомпоновкиДанных;
МакетКомпоновки = КомпоновщикМакета.Выполнить(СхемаКомпоновкиДанных, Настройки);
      
//ПроцессорКомпоновки
ПроцессорКомпДанных = Новый ПроцессорКомпоновкиДанных;
НаборыДанных = Новый Структура("РезультатСравнения", РезультатСравнения);
ПроцессорКомпДанных.Инициализировать(МакетКомпоновки, НаборыДанных, ДанныеРасшифровки);
      
//ПроцессорВывода
ПроцессорВывода = Новый ПроцессорВыводаРезультатаКомпоновкиДанныхВТабличныйДокумент;
ПроцессорВывода.УстановитьДокумент(ДокументРезультат);
ПроцессорВывода.Вывести(ПроцессорКомпДанных, Истина);

Что я упустил?

Так и было. Исправил это:

Код:

МакетКомпоновки = КомпоновщикМакета.Выполнить(СхемаКомпоновкиДанных, Настройки);

Таким образом:

Код:

МакетКомпоновки = КомпоновщикМакета.Выполнить(СхемаКомпоновкиДанных, Настройки, ДанныеРасшифровки);

И заработало