8.х Почему не срабатывает печать шапки на каждой странице?

Существует процедура для формирования отчета. Почему шапка не печатается на каждой странице?(В цикле точно также не срабатывает)

Код:

Процедура СформироватьОтчет(Кнопка)
ДанныеЗаполнены = Истина;
Если Счет = ПланыСчетов.Хозрасчетный.ПустаяСсылка() Тогда
Сообщить("Не выбран счет!");
ДанныеЗаполнены = Ложь;
КонецЕсли;
Если Склад = Справочники.Склады.ПустаяСсылка() Тогда
Сообщить("Не выбран склад!");
ДанныеЗаполнены = Ложь;
КонецЕсли;
Если ДанныеЗаполнены Тогда
ЭлементыФормы.Результат.Очистить();
КомпоновщикМакета = Новый КомпоновщикМакетаКомпоновкиДанных;
Параметры = КомпоновщикНастроек.Настройки.ПараметрыДанных;
Параметры.УстановитьЗначениеПараметра("НачалоПериода", ДатаНач);
Параметры.УстановитьЗначениеПараметра("КонецПериода",ДатаКон);
Параметры.УстановитьЗначениеПараметра("Счет", Счет);
Параметры.УстановитьЗначениеПараметра("Склад", Склад);

МакетКомпоновки = КомпоновщикМакета.Выполнить(СхемаКомпоновкиДанных, КомпоновщикНастроек.Настройки,);
ПроцессорКомпоновки = Новый ПроцессорКомпоновкиДанных;
ПроцессорКомпоновки.Инициализировать(МакетКомпоновки, ,, Истина);
ДокументРезультат = ЭлементыФормы.Результат;
ДокументРезультат.АвтоМасштаб = Истина;
Макет = ПолучитьМакет("Шапка");
ОбластьЗаголовок = Макет.ПолучитьОбласть("Вывести");
Если ДатаНач = Дата(1,1,1) И ДатаКон = Дата(1,1,1) Тогда
Период	 = "без ограничения.";
Иначе
Если ДатаНач = Дата(1,1,1) ИЛИ ДатаКон = Дата(1,1,1) Тогда
Период = Формат(ДатаНач, "ДФ = ""дд.ММ.гггг""; ДП = ""без ограничения""")
+ " - " + Формат(ДатаКон, "ДФ = ""дд.ММ.гггг""; ДП = ""без ограничения""");
Иначе
Период = ПредставлениеПериода(НачалоДня(ДатаНач), КонецДня(ДатаКон), "ФП = Истина");
КонецЕсли;
КонецЕсли;
ОбластьЗаголовок.Параметры.Период	 = Период;
ОбластьЗаголовок.Параметры.Склад	  = Склад;
ОбластьЗаголовок.Параметры.ОтветЛицо  = ОтветЛицо;
ДокументРезультат.Вывести(ОбластьЗаголовок);
ПроцессорВывода = Новый ПроцессорВыводаРезультатаКомпоновкиДанныхВТабличныйДокумент;
ПроцессорВывода.УстановитьДокумент(ЭлементыФормы.Результат);


ДокументРезультат.НижнийКолонтитул.Выводить = Истина;
ДокументРезультат.НижнийКолонтитул.НачальнаяСтраница = 2;

ДокументРезультат.НижнийКолонтитул.ТекстВЦентре = "Стр. [&НомерСтраницы] из [&СтраницВсего]";

ДокументРезультат.ПовторятьПриПечатиСтроки = ДокументРезультат.Область("R5C1:R8C11"); //<--почему не работает, ошибок нет!

Попытка
ПроцессорВывода.НачатьВывод();
Пока Истина Цикл
ОбработкаПрерыванияПользователя();
ЭлементРезультата = ПроцессорКомпоновки.Следующий();
Если ЭлементРезультата = Неопределено Тогда
Прервать;
Иначе
ПроцессорВывода.ВывестиЭлемент(ЭлементРезультата);
//ДокументРезультат.ПовторятьПриПечатиСтроки = ДокументРезультат.Область("R5C1:R8C11");
КонецЕсли;

КонецЦикла;
Исключение
Сообщить(ОписаниеОшибки(), СтатусСообщения.Важное);
КонецПопытки;
;
КонецЕсли;

КонецПроцедуры

А д/б так:

Код:

ДокументРезультат.ПовторятьПриПечатиСтроки = ДокументРезультат.Область("R5:R8");

См. Синтакс-Помощник.