8.х Почему срабатывают транзакционные блокировки?

Видимо я что-то не понимаю, почему срабатывают транзакционные блокировки если я установил режим блокировок управляемые и нигде не описывал блокировки вообще. По идее в этом случае блокировки не накладываются? А по факту они существуют.

Кто вам сказал, что блокировки не накладываются?
Они очень даже накладываются.....

А для объекта установлен управляемый режим?
Обычно перед записью задачи пытаются блокировать её.

Код:

Попытка
ЗаблокироватьДанныеДляРедактирования(ЗадачаОбъект);
Исключение
//...
КонецПопытки

А вообще, странная задача - выполнять интерактивное завершение задачи пользователя.

Хорошо, буду читать про блокировки... мне почему-то казалось, что если управляемый установить, то они не накладываются в клиент-серверном варианте. Вот только после того, как опишу пространства имен блокировки, и только после того как напишу Заблокировать() все должно блокироваться... и тогда уже такие сообщения появляться...

Да, для всех объектов конфигурации отдельно тоже установил управляемый режим. Насколько я понимаю, сейчас интерактивно выполнить задачу можно только программно, когда выполняется задача пользователем то такой обработчик не вызывается.

Понятно...ничего не понятно
Может задача стоит в другом? При выполнении задачи бизнес процесса "Согласование разрешения на оплату произвольного" нужно что-то выполнить? Зачем имитировать интерактивное выполнение задачи?

Транзакционные блокировки работают ВСЕГДА, иначе в БД случилась бы "каша" из данных.
Управляемые блокировки нужны, чтобы управлять количеством одновременно заблокированных данных.

Написано что там ссылочные данные указываются для блокировки... Если укажу, то при ошибке блокировки можно эту ошибку обработать, правильно?

Вроде да, вот пример:

Код:

Процедура ОбработкаРезультатовСогласованияОбработка(ТочкаМаршрутаБизнесПроцесса)
   
    УстановитьПривилегированныйРежим(Истина);
   
    ЗаявкаОбъект = Заявка.ПолучитьОбъект();
   
    Если ЗаявкаОбъект.Состояние <> Перечисления.СостоянияЗаявокНаРазмещение.Согласована Тогда
        Попытка
            ЗаблокироватьДанныеДляРедактирования(Заявка);
        Исключение
            ТекстСообщения = СтроковыеФункцииКлиентСервер.ПодставитьПараметрыВСтроку(
                НСтр("ru = 'В ходе обработки результатов согласования не удалось заблокировать %1. %2'"),
                Строка(Заявка),
                КраткоеПредставлениеОшибки(ИнформацияОбОшибке())
            );
            ВызватьИсключение ТекстСообщения;
        КонецПопытки;
       
        ЗаявкаОбъект.Состояние = Перечисления.СостоянияЗаявокНаРазмещение.Согласована;
       
        Попытка
            ЗаявкаОбъект.Записать();
            РазблокироватьДанныеДляРедактирования(Заявка);
        Исключение
            РазблокироватьДанныеДляРедактирования(Заявка);
           
            ТекстСообщения = СтроковыеФункцииКлиентСервер.ПодставитьПараметрыВСтроку(
                НСтр("ru = 'Не удалось записать %1. %2'"),
                Строка(Заявка),
                КраткоеПредставлениеОшибки(ИнформацияОбОшибке())
            );
            ВызватьИсключение ТекстСообщения;
        КонецПопытки
    КонецЕсли;
   
    УстановитьПривилегированныйРежим(Ложь);
   
КонецПроцедуры // ОбработкаРезультатовСогласованияОбработка()

Спасибо большое! А в %1 и %2 содержится информация об ошибках при исключительной ситуации?

Код:

// Подставляет параметры в строку. Максимально возможное число параметров - 9.
// Параметры в строке задаются как %<номер параметра>. Нумерация параметров начинается с единицы.
//
// Параметры:
//  СтрокаПодстановки  - Строка - шаблон строки с параметрами (вхождениями вида "%ИмяПараметра");
//  Параметр<n>        - Строка - подставляемый параметр.
//
// Возвращаемое значение:
//  Строка   - текстовая строка с подставленными параметрами.
//
// Пример:
//  ПодставитьПараметрыВСтроку(НСтр("ru='%1 пошел в %2'"), "Вася", "Зоопарк") = "Вася пошел в Зоопарк".
//
// Примечание:
//  В случаях, когда число используемых параметров в строке совпадает с числом переданных для подстановки параметров,
//  рекомендуется использовать функцию платформы СтрШаблон.
Функция ПодставитьПараметрыВСтроку(Знач СтрокаПодстановки,
    Знач Параметр1, Знач Параметр2 = Неопределено, Знач Параметр3 = Неопределено,
    Знач Параметр4 = Неопределено, Знач Параметр5 = Неопределено, Знач Параметр6 = Неопределено,
    Знач Параметр7 = Неопределено, Знач Параметр8 = Неопределено, Знач Параметр9 = Неопределено) Экспорт
   
    ИспользоватьАльтернативныйАлгоритм =
        СтрНайти(Параметр1, "%")
        Или СтрНайти(Параметр2, "%")
        Или СтрНайти(Параметр3, "%")
        Или СтрНайти(Параметр4, "%")
        Или СтрНайти(Параметр5, "%")
        Или СтрНайти(Параметр6, "%")
        Или СтрНайти(Параметр7, "%")
        Или СтрНайти(Параметр8, "%")
        Или СтрНайти(Параметр9, "%");
       
    Если ИспользоватьАльтернативныйАлгоритм Тогда
        СтрокаПодстановки = ПодставитьПараметрыВСтрокуАльтернативныйАлгоритм(СтрокаПодстановки, Параметр1,
            Параметр2, Параметр3, Параметр4, Параметр5, Параметр6, Параметр7, Параметр8, Параметр9);
    Иначе
        СтрокаПодстановки = СтрЗаменить(СтрокаПодстановки, "%1", Параметр1);
        СтрокаПодстановки = СтрЗаменить(СтрокаПодстановки, "%2", Параметр2);
        СтрокаПодстановки = СтрЗаменить(СтрокаПодстановки, "%3", Параметр3);
        СтрокаПодстановки = СтрЗаменить(СтрокаПодстановки, "%4", Параметр4);
        СтрокаПодстановки = СтрЗаменить(СтрокаПодстановки, "%5", Параметр5);
        СтрокаПодстановки = СтрЗаменить(СтрокаПодстановки, "%6", Параметр6);
        СтрокаПодстановки = СтрЗаменить(СтрокаПодстановки, "%7", Параметр7);
        СтрокаПодстановки = СтрЗаменить(СтрокаПодстановки, "%8", Параметр8);
        СтрокаПодстановки = СтрЗаменить(СтрокаПодстановки, "%9", Параметр9);
    КонецЕсли;
   
    Возврат СтрокаПодстановки;
КонецФункции

Спасибо, красиво придумано.

В моем случае блокировка появилась во время записи в регистр сведений через МенеджерЗаписи во время транзакции. При чем это новая запись, ранее ее в регистре не было с таким ключом.

Спасибо. Получается у меня в транзакции есть запись в регистре сведений, т.к. блокировки управляемые и не описано пространство блокировки по каким полям блокировать, то накладывается блокировка на всю таблицу.

Там менеджер, при чем по одному измерению с одним значением в РС исключена запись параллельно у двух пользователей. Буду смотреть ТЖ, просто ошибка плавающая.

Недавно отловил блокировку:

Код:

03:33.576000-0,TTIMEOUT,5,process=rphost,p:processName=SO_DB,t:clientID=255,t:applicationName=1CV8C,t:computerName=1C-APP,t:connectID=79,SessionID=25,Usr=Пользователь,AppID=1CV8C,WaitConnections=90,Context='Форма.Вызов : Документ.РазрешениеНаОплатуПроизвольное.Форма.ФормаЭлемента.Модуль.СогласенНаСервере
Документ.РазрешениеНаОплатуПроизвольное.Форма.ФормаЭлемента.Форма : 40 : ЗадачаОбъект.ВыполнитьЗадачуИнтерактивно();

Тут написано все то же что платформа показывает при ошибке, все та же ошибка в ЗадачеОбъекте при методе ВыполнитьЗадачуИнтерактивно(). Даже знаю по какой причине возникает ошибка: у меня в транзакции этого метода пишется запись только в один РС через МенеджерЗаписи. Но мне по любому нужно туда писать инфу в этот служебный РС. Поэтому наложу ограничение в пространство блокировки, сейчас у меня просто не описываются блокировки по этой таблице РС, поэтому блокируется она вся, и параллельно другие пользователи тоже пишут туда, наверно из-за этого и ошибка...

--- Объединение сообщений, 19 май 2017 ---

если так, то тогда вообще нету в коде ничего что может повлиять на выполнение транзакции...

Понятно, спасибо.