8.х ОБМЕН При обработке, чтобы объекты не попадали в план обмена полный

После выполнения ваших операций по очистке можете снять с регистрации объекты которые будут зарегистрированы к обмену.
Но всё же вы что то не то делаете.

Направляю ряд законченных обработчиков
Процедуру вызываете для обработчика. Перед употреблением встряхнуть на тестовой базе

Код:

Процедура ВыполнитьЗапись(ДокументОбъект)
   
    ДокументОбъект.ОбменДанными.Получатели.Очистить();
    ДокументОбъект.ОбменДанными.Получатели.Автозаполнение = ложь;
    МассивРегистраций = ПолучитьУзлыВКоторыхДокументЗарегистрирован(ДокументОбъект); // формирует массив уже имеющихся регистраций
      
    Если ДокументОбъект.Проведен Тогда
        Попытка
            ДокументОбъект.Записать(РежимЗаписиДокумента.Проведение, РежимПроведенияДокумента.Неоперативный);
        Исключение
            ТекстОшибки = ОписаниеОшибки();
            Сообщить(ТекстОшибки);
        КонецПопытки;
       
    Иначе
        Попытка
            ДокументОбъект.Записать(РежимЗаписиДокумента.Запись);
        Исключение
            Сообщить(ОписаниеОшибки());
        КонецПопытки;
       
    КонецЕсли;
   
    СнятьРегистрациюСУзлов(ДокументОбъект); // снимает всю регистрацию
    ЗарегистрироватьНаОбмен(МассивРегистраций); // возвращает регистрацию из массива
   
КонецПроцедуры

Функция ПолучитьУзлыВКоторыхДокументЗарегистрирован(ДокументОбъект)
   
    МассивРегистраций = Новый Массив;
    Для каждого ПланМенеджер из ПланыОбмена Цикл
        ПланУзелВыборка = ПланМенеджер.Выбрать();
        Пока ПланУзелВыборка.Следующий() Цикл
            ПланУзел = ПланУзелВыборка.Ссылка;
            // нельзя проверять свой же узел ена изменения
            Если ПланМенеджер.ЭтотУзел() = ПланУзел Тогда
                Продолжить;
            КонецЕсли;
            Если ПланыОбмена.ИзменениеЗарегистрировано(ПланУзел, ДокументОбъект.Ссылка) Тогда
                Структура = Новый Структура;
                Структура.Вставить("Менеджер", ПланМенеджер);
                Структура.Вставить("Узел", ПланУзел);
                Структура.Вставить("Объект", ДокументОбъект.Ссылка);
                МассивРегистраций.Добавить(Структура);
            КонецЕсли;
        КонецЦикла;
    КонецЦикла;
    Возврат МассивРегистраций;
   
КонецФункции

Процедура СнятьРегистрациюСУзлов(ДокументОбъект)
   
    Для каждого ПланМенеджер из ПланыОбмена Цикл
        ПланУзелВыборка = ПланМенеджер.Выбрать();
        Пока ПланУзелВыборка.Следующий() Цикл
            ПланУзел = ПланУзелВыборка.Ссылка;
            // нельзя проверять свой же узел ена изменения
            Если ПланМенеджер.ЭтотУзел() = ПланУзел Тогда
                Продолжить;
            КонецЕсли;
            // удалить регистрацию можно только если она разрешена
            Попытка
                ПланыОбмена.УдалитьРегистрациюИзменений(ПланУзел, ДокументОбъект.Ссылка);
            Исключение
               
            КонецПопытки;
        КонецЦикла;
    КонецЦикла;
   
КонецПроцедуры

Процедура ЗарегистрироватьНаОбмен(МассивРегистраций)
   
    Для каждого стр из МассивРегистраций Цикл
        ПланМенеджер = стр.Менеджер;
        ПланУзел = стр.Узел;
        Объект = стр.Объект;
        ПланыОбмена.ЗарегистрироватьИзменения(ПланУзел, Объект);
    КонецЦикла;
   
КонецПроцедуры