8.х Проблема с подбором при поступлении товаров

1. Обновите на 10.3.22
2. Проверьте в модуле формы документа процедуру, она должна совпадать один в один, это та процедура которая конкретно заполняет товар в табличную часть документа, у каждой формы документа она своя. Убедитесь что конфигурация в частности и эта процедура типовые, ибо на типовой 10.3.22 проверил, проблем нет

Код:

Процедура ОбработкаПодбора(ТабличнаяЧасть, ЗначениеВыбора)Экспорт
Перем СпособЗаполненияЦен, ВалютаЦены, ЕстьСкладВТабличнойЧасти;
Перем Номенклатура, ЕдиницаИзмерения, Количество, КоличествоМест, Цена, Характеристика, Серия;
Если РаботаСДиалогами.ПроверитьЧтоКачествоВСтруктуреПодбораНеУдовлетворяетУсловиямПодбора(ЗначениеВыбора,
Истина) Тогда
Возврат;
КонецЕсли;
// Получим параметры подбора из структуры подбора.
ЗначениеВыбора.Свойство("СпособЗаполненияЦен", СпособЗаполненияЦен);
ЗначениеВыбора.Свойство("ВалютаЦены"		 , ВалютаЦены);
ЗначениеВыбора.Свойство("Номенклатура"    , Номенклатура);
ЗначениеВыбора.Свойство("ЕдиницаИзмерения", ЕдиницаИзмерения);
ЗначениеВыбора.Свойство("Количество"	  , Количество);
ЗначениеВыбора.Свойство("КоличествоМест"  , КоличествоМест);
ЗначениеВыбора.Свойство("Цена"		    , Цена);
ЗначениеВыбора.Свойство("Характеристика"  , Характеристика);
ЗначениеВыбора.Свойство("Серия"		   , Серия);
Если НЕ ЗначениеВыбора.Свойство("ЕстьСкладВТабличнойЧасти", ЕстьСкладВТабличнойЧасти) Тогда
ЕстьСкладВТабличнойЧасти = Ложь;
КонецЕсли;
Если (ТабличнаяЧасть = Товары ИЛИ ТабличнаяЧасть = ВозвратнаяТара )
И Номенклатура.Услуга Тогда
Предупреждение("В данном контексте услуги не подбираются!");
Возврат;
ИначеЕсли ТабличнаяЧасть = Услуги И Не Номенклатура.Услуга Тогда
Предупреждение("В данном контексте товары не подбираются!");
Возврат;
КонецЕсли;
// Ищем выбранную позицию в таблице подобранной номенклатуры.
//  Если найдем - увеличим количество; не найдем - добавим новую строку.
СтруктураОтбора = Новый Структура();
Если ТабличнаяЧасть = Товары Тогда
СтруктураОтбора.Вставить("ЕдиницаИзмерения", ЕдиницаИзмерения);
СтруктураОтбора.Вставить("ХарактеристикаНоменклатуры", Характеристика);
СтруктураОтбора.Вставить("СерияНоменклатуры"		 , Серия);
Иначе
СтруктураОтбора.Вставить("Номенклатура", Номенклатура);
КонецЕсли;
Если ЕстьСкладВТабличнойЧасти
И ТабличнаяЧасть <> Услуги
И ВидПоступления = Перечисления.ВидыПоступленияТоваров.НаСклад
И ЗначениеЗаполнено(СкладОрдер) Тогда
СтруктураОтбора.Вставить("Склад", СкладОрдер);
КонецЕсли;
СтрокаТабличнойЧасти = ОбработкаТабличныхЧастей.НайтиСтрокуТабЧасти(ТабличнаяЧасть, СтруктураОтбора);
Если СтрокаТабличнойЧасти <> Неопределено Тогда
Если ТабличнаяЧасть = Товары Тогда
// Нашли, увеличиваем количество в первой найденной строке.
СтрокаТабличнойЧасти.Количество = СтрокаТабличнойЧасти.Количество + Количество;
Если НЕ ЗначениеЗаполнено(СтрокаТабличнойЧасти.ЗаказПоставщику)
И ТипЗнч(Сделка) = Тип("ДокументСсылка.ЗаказПоставщику") Тогда
СтрокаТабличнойЧасти.ЗаказПоставщику = Сделка;
КонецЕсли;
// Рассчитать реквизиты табличной части.
ОбработкаТабличныхЧастей.РассчитатьКоличествоМестТабЧасти(СтрокаТабличнойЧасти, ЭтотОбъект);
ОбработкаТабличныхЧастей.РассчитатьСуммуТабЧасти(СтрокаТабличнойЧасти, ЭтотОбъект);
ОбработкаТабличныхЧастей.РассчитатьСуммуНДСТабЧасти(СтрокаТабличнойЧасти, ЭтотОбъект);
ИначеЕсли ТабличнаяЧасть = ВозвратнаяТара Тогда
// Нашли, увеличиваем количество в первой найденной строке.
СтрокаТабличнойЧасти.Количество = СтрокаТабличнойЧасти.Количество + Количество;
Если НЕ ЗначениеЗаполнено(СтрокаТабличнойЧасти.ЗаказПоставщику)
И ТипЗнч(Сделка) = Тип("ДокументСсылка.ЗаказПоставщику") Тогда
СтрокаТабличнойЧасти.ЗаказПоставщику = Сделка;
КонецЕсли;
// Рассчитать реквизиты табличной части.
ОбработкаТабличныхЧастей.РассчитатьСуммуВозвратнойТарыТабЧасти(СтрокаТабличнойЧасти, ЭтотОбъект);

ИначеЕсли ТабличнаяЧасть = Услуги Тогда
// Нашли, увеличиваем количество в первой найденной строке.
СтрокаТабличнойЧасти.Количество = СтрокаТабличнойЧасти.Количество + Количество;
Если НЕ ЗначениеЗаполнено(СтрокаТабличнойЧасти.ЗаказПоставщику)
И ТипЗнч(Сделка) = Тип("ДокументСсылка.ЗаказПоставщику") Тогда
СтрокаТабличнойЧасти.ЗаказПоставщику = Сделка;
КонецЕсли;
// Рассчитать реквизиты табличной части.
ОбработкаТабличныхЧастей.РассчитатьКоличествоМестТабЧасти(СтрокаТабличнойЧасти, ЭтотОбъект);
ОбработкаТабличныхЧастей.РассчитатьСуммуТабЧасти(СтрокаТабличнойЧасти, ЭтотОбъект);
ОбработкаТабличныхЧастей.РассчитатьСуммуНДСТабЧасти(СтрокаТабличнойЧасти, ЭтотОбъект);
КонецЕсли;
Иначе
// Не нашли - добавляем новую строку.
СтрокаТабличнойЧасти = ТабличнаяЧасть.Добавить();
СтрокаТабличнойЧасти.Номенклатура	 = Номенклатура;
Если ТабличнаяЧасть = Товары Тогда
СтрокаТабличнойЧасти.Количество	   = Количество;
СтрокаТабличнойЧасти.ЕдиницаИзмерения = ЕдиницаИзмерения;
СтрокаТабличнойЧасти.Коэффициент	  = СтрокаТабличнойЧасти.ЕдиницаИзмерения.Коэффициент;
СтрокаТабличнойЧасти.ХарактеристикаНоменклатуры = Характеристика;
СтрокаТабличнойЧасти.СерияНоменклатуры		  = Серия;
Если ТипЗнч(Сделка) = Тип("ДокументСсылка.ЗаказПоставщику") Тогда
СтрокаТабличнойЧасти.ЗаказПоставщику = Сделка;
КонецЕсли;
Если Не УправлениеЗаказами.ИспользоватьВнутренниеЗаказы() Тогда
СтрокаТабличнойЧасти.Заказ = Документы.ЗаказПокупателя.ПустаяСсылка();
КонецЕсли;
// Заполняем реквизиты табличной части.
ОбработкаТабличныхЧастей.ЗаполнитьСтавкуНДСТабЧасти(СтрокаТабличнойЧасти, ЭтотОбъект, "Приобретение");
// Пересчитаем цену в валюту документа.
Цена = Ценообразование.ПересчитатьЦенуПриИзмененииВалюты(Цена, ВалютаЦены, ВалютаДокумента, ЗаполнениеДокументов.КурсДокумента(ЭтотОбъект, мВалютаРегламентированногоУчета), ЗаполнениеДокументов.КратностьДокумента(ЭтотОбъект, мВалютаРегламентированногоУчета), Дата);
СтрокаТабличнойЧасти.Цена = Ценообразование.ПересчитатьЦенуПриИзмененииФлаговНалогов(Цена,
СпособЗаполненияЦен,
ТипЦен.ЦенаВключаетНДС,
УчитыватьНДС,
СуммаВключаетНДС,
УчетНДС.ПолучитьСтавкуНДС(СтрокаТабличнойЧасти.СтавкаНДС));
// Рассчитываем реквизиты табличной части.
ОбработкаТабличныхЧастей.ЗаполнитьЕдиницуМестТабЧасти(СтрокаТабличнойЧасти, ЭтотОбъект, Ложь);
ОбработкаТабличныхЧастей.РассчитатьСуммуТабЧасти(СтрокаТабличнойЧасти, ЭтотОбъект);
ОбработкаТабличныхЧастей.РассчитатьСуммуНДСТабЧасти(СтрокаТабличнойЧасти, ЭтотОбъект);
ИначеЕсли ТабличнаяЧасть = ВозвратнаяТара Тогда
СтрокаТабличнойЧасти.Количество = Количество;
Если Не УправлениеЗаказами.ИспользоватьВнутренниеЗаказы() Тогда
СтрокаТабличнойЧасти.Заказ = Документы.ЗаказПокупателя.ПустаяСсылка();
КонецЕсли;
Если ТипЗнч(Сделка) = Тип("ДокументСсылка.ЗаказПоставщику") Тогда
СтрокаТабличнойЧасти.ЗаказПоставщику = Сделка;
КонецЕсли;

// Пересчитаем цену в валюту документа.
Цена = Ценообразование.ПересчитатьЦенуПриИзмененииВалюты(Цена, ВалютаЦены, ВалютаДокумента, ЗаполнениеДокументов.КурсДокумента(ЭтотОбъект, мВалютаРегламентированногоУчета), ЗаполнениеДокументов.КратностьДокумента(ЭтотОбъект, мВалютаРегламентированногоУчета), Дата);
// Если цену заполнили из регистра, то ее надо пересчитывать по флагам налогообложения.
// Считаем, что оценочную стоимость возвратной тары всегда задают с НДС
// ставки берутся из номенклатуры.
СтрокаТабличнойЧасти.Цена = Ценообразование.ПересчитатьЦенуПриИзмененииФлаговНалогов(Цена,
СпособЗаполненияЦен,
ТипЦен.ЦенаВключаетНДС,
УчитыватьНДС,
Истина,
УчетНДС.ПолучитьСтавкуНДС(СтрокаТабличнойЧасти.Номенклатура.СтавкаНДС));
// Рассчитать реквизиты табличной части.
ОбработкаТабличныхЧастей.РассчитатьСуммуВозвратнойТарыТабЧасти(СтрокаТабличнойЧасти, ЭтотОбъект);
ИначеЕсли ТабличнаяЧасть = Услуги Тогда
СтрокаТабличнойЧасти.Количество = Количество;
Если ТипЗнч(Сделка) = Тип("ДокументСсылка.ЗаказПоставщику") Тогда
СтрокаТабличнойЧасти.ЗаказПоставщику = Сделка;
КонецЕсли;
// Заполняем реквизиты табличной части.
ОбработкаТабличныхЧастей.ЗаполнитьСодержаниеТабЧасти(СтрокаТабличнойЧасти, ЭтотОбъект);
ОбработкаТабличныхЧастей.ЗаполнитьСтавкуНДСТабЧасти(СтрокаТабличнойЧасти, ЭтотОбъект, "Приобретение");
// Пересчитаем цену в валюту документа.
Цена = Ценообразование.ПересчитатьЦенуПриИзмененииВалюты(Цена, ВалютаЦены, ВалютаДокумента, ЗаполнениеДокументов.КурсДокумента(ЭтотОбъект, мВалютаРегламентированногоУчета), ЗаполнениеДокументов.КратностьДокумента(ЭтотОбъект, мВалютаРегламентированногоУчета), Дата);
СтрокаТабличнойЧасти.Цена = Ценообразование.ПересчитатьЦенуПриИзмененииФлаговНалогов(Цена,
СпособЗаполненияЦен,
ТипЦен.ЦенаВключаетНДС,
УчитыватьНДС,
СуммаВключаетНДС,
УчетНДС.ПолучитьСтавкуНДС(СтрокаТабличнойЧасти.СтавкаНДС));
// Рассчитываем реквизиты табличной части.
ОбработкаТабличныхЧастей.РассчитатьСуммуТабЧасти(СтрокаТабличнойЧасти, ЭтотОбъект);
ОбработкаТабличныхЧастей.РассчитатьСуммуНДСТабЧасти(СтрокаТабличнойЧасти, ЭтотОбъект);

СтрокаТабличнойЧасти.СтатьяЗатрат = СтрокаТабличнойЧасти.Номенклатура.СтатьяЗатрат;
СтрокаТабличнойЧасти.НоменклатурнаяГруппа = СтрокаТабличнойЧасти.Номенклатура.НоменклатурнаяГруппаЗатрат;
КонецЕсли;
КонецЕсли; // СтрокаТабличнойЧасти <> Неопределено
Если ТабличнаяЧасть <> Услуги Тогда
ОбработкаТабличныхЧастей.ЗаполнитьСкладИОрдерТабЧасти(СтрокаТабличнойЧасти, ЭтотОбъект);
КонецЕсли;
ТабличнаяЧастьИмя = ?(ТабличнаяЧасть = Товары, "Товары", "ВозвратнаяТара");
ЭлементыФормы[ТабличнаяЧастьИмя].ТекущаяСтрока = СтрокаТабличнойЧасти;
ЭлементыФормы[ТабличнаяЧастьИмя].ТекущаяКолонка = ЭлементыФормы[ТабличнаяЧастьИмя].Колонки["Количество"];
КонецПроцедуры // ОбработкаПодбора()

Хотя, нужно мне еще самому глянуть вот этот участок кода

Такое ощещение что сама номенклатура не участвует в поиске, а только единица характеристика и серия

Посмотрел код как и обещал, там интересно, у Вас скорее всего с единицами измерения проблемы. Справочник "Единицы измерения" подчинен номенклатуре. При подборе выполняется поиск совпадающих единиц измерения и если база была закосячена, то программа будет считать что это один и тот же товар, ибо единица измерения общая. Могли похерить, например, обработкой поиск и замена дублей, где при сравнении наименование одинаковое, а владелец на самом деле разный. Такая же проблема могла возникнуть при переносах данных (не типовых) и программно подставлять найденную единицу измерения при этом не учитывая того факта что данная единица не принадлежит данному товару. Сравните владельцев единиц измерения того товара который у Вас складывается, все таки думаю там один и тот же владелец.